ByteMode={{0,1,0,0}};
文字数[data_]:={IntegerDigits[
Length[ToCharacterCode[data,"UTF-8"]],2,8]};
文字Data[data_]:=Map[IntegerDigits[#,2,8] &,
ToCharacterCode[data,"UTF-8"]];
終端Pattern={{0,0,0,0}};
文字情報語[data_]:=Partition[
Partition[Flatten[
Join[ByteMode,文字数[data],文字Data[data],終端Pattern]],
8,8,1,0],
13,13,1,{{1,1,1,0,1,1,0,0},
{0,0,0,1,0,0,0,1}}][[1]];

生成元=(γ^8)+(γ^4)+(γ^3)+(γ^2)+1;
加法表示[x_]:=PolynomialMod[x,{生成元,2}]
F256=Prepend[Table[加法表示[(γ^k)],{k,0,254}],0];
位置[L_,e_]:=Position[L,e][[1]][[1]];
乗法表示[x_]:=If[x===0,0,γ^(位置[F256,加法表示[x]]-2)];
生成多項式 =PolynomialMod[Product[(x+(γ^k)),{k,0,12}],{生成元,2}];
情報多項式[word_]:=Map[加法表示[#.Table[(γ^((7-i))),{i,0,7}]]&,word
].Table[x^(13-i),{i,1,13}];
符号多項式[poly_]:=
Collect[PolynomialMod[
poly*x^13+PolynomialRemainder[poly*x^13,生成多項式,x],
{生成元,2}],x];
送信語[poly_]:=Mod[Map[Table[Coefficient[加法表示[#],γ,7-i],{i,0,7}] &,Table[Coefficient[poly,x,25-i],
{i,0,25}]],2];

氏名="(*名前を入れる*)";

文字情報語[氏名]

文字情報語[氏名]//TableForm

情報多項式[文字情報語[氏名]]//TraditionalForm

符号多項式[情報多項式[文字情報語[氏名]]]//TraditionalForm

ExportString[Table[送信語[符号多項式[情報多項式[文字情報語[氏名]]]][[i]],{i,1,26}],"TSV"]